RP2040 SDKなし3 割り込み
前回UARTで通信する際、FIFOにデータが届いていないかを確認しつづけていた（ポーリング）。 これでは電力がもったいないので、データが届くまでCPUは休ませておいて、 届いたときだけ処理を実行するように変更する（割り込み）。
前回: RP2040 SDKなし2 Clock、UART
ソースコード: git/ex3_interrupt
動作環境
- OpenBSD 7.7
- arm-none-eabi-binutils-2.40
- OpenBSD Make
- minicom version 2.8
- FT234X 超小型USBシリアル変換モジュール
割り込み
ハードウェアが外部から信号を受けとると、CPUに現在の処理を中断させてその信号を処理させるようにできる。これを割り込み処理という。今回はUARTにデータが届いた時に同じデータをUARTに書き込むようにしたい。
割り込みを有効化
割り込みの信号を受け取るために、割り込みを有効化する。CPUが割り込みを受け付けるようにする設定と、UARTが割り込み信号を発生させるようにする設定が必要である。
CPU側の設定はM0PLUS: NVIC_ISERレジスタの有効化したい割り込みのビットに1を書くことで行う。有効化できる割り込みは全部で26個ある。割り込みの種類はrp2040のデータシート[1]のTable 80. Interruptsに書いてある。今回有効化するのはUART0の割り込みで、この表から20番が割り当てられていることが分かるので、M0PLUS: NVIC_ISERに、下から20番目のビットを1にしたもの書き込む:
// enable uart interrupt in cpu
ldr r4, ppb_base
mov r5, #0xe1
lsl r5, #8
mov r0, #1
lsl r0, #20
str r0, [r4, r5] // M0PLUS: NVIC_ISER
/* ... */
ppb_base:
.word 0xe0000000
UART側の設定は、UART: UARTIMSCレジスタで行なう。データを受け取ったときに割り込みを発生させたいので、RXIMビットに1を書き込む。また、処理を開始する前に既にFIFOにデータがたまっている可能性があるので、FIFOが空ではないときに割り込みを発生させるように、RTIMにも1を書き込む:
// enable uart interrupt in uart0 subsystem
ldr r1, uart0_base
mov r2, #(1 << 6 | 1 << 4) // RTIM | RXIM
str r2, [r1, #0x38] // UART: UARTIMSC
また、FIFOにデータがきたらすぐに割り込みを発生させたいので、UART: UARTIFLSレジスタのRXIFLSELに0を書き込む。これでFIFOの1/8が埋まったら割り込みが発生する。
// set fifo level to 0
mov r2, #0
str r2, [r1, #0x34] // UART: UARTIFLS
これだとFIFOに届いた瞬間には割り込みがおこらない気がするが、pico-sdk（src/rp2_common/hardware_uart/include/hardware/uart.h）のuart_set_irqs_enabled関数でもこうなってる。FIFOを無効にすれば即座に割り込みがおこるかもしれないが、データが失われる可能性もあるのかな。
ベクターテーブルの設定
外部からの信号で割り込みが発生したときにCPUに行わせる処理はベクターテーブルにあらかじめ登録しておく必要がある。ベクターテーブルの場所は一回目に登録した通りvectorsとラベルを付けた場所（main.sの先頭）である。ARMの仕様書[2]によると、ベクターテーブルの0番目は初期のスタックポインタで、そこから15個はARMによって使用用途が定められている。16番以降の32個は各CPUの設計者が自由に決められる。rp2040の割り込みについてはデータシート[1]のTable 80. Interruptsに一覧表が載っている。今回使いたいのはUART0の割り込みなので16 + 20 = 36番目に、割り込み時に呼ばれたい関数のポインタ（Thumb Modeなので関数のアドレスに1を足したもの）を書き込めばいい。それ以外のものは今回は使わないので適当な数値でうめておく:
.global vectors
vectors:
.word 0x20040000 // initial SP
.word (reset+1) // entry point
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word 0xdeadbeef
.word (uart_interrupt_handler+1) // UART0_IRQ
割り込み処理
割り込み発生時に呼ばれる関数はUARTのFIFOに届いたデータをそのまま送信するだけのものである:
// uart_interrupt_handler echos the data arrived at uart0
uart_interrupt_handler:
push {lr}
bl getbyte
bl putbyte
pop {pc}
getbyte、putbyteは前回と同じもの。
メインループ
UARTにデータが届いていないときは特にすることがないのでCPUは寝かせておく。ARMには割り込みが発生するまでなにもしないwfeという命令があるのでこれを使う:
loop:
wfe
b loop
完成
これで完成。動作は前回と全く同じだが、消費電力をおさえられる。